How to time a script in DOS?

Asked
Viewd14754

5

How do you time a script in the DOS prompt?

The *NIX equivanlent would be:

$ time myscript

real 0m0.886s
user 0m0.846s
sys 0m0.031s

$

Is there a DOS equivalent to this? Thanks

14754

4 ответов

5

you can put this at the start and end of your batch:

echo %time%
  • the only way I guess. +1

    dmityugov22 сентября 2009, 21:12
5

вы можете использовать timeit.exe из Пакет ресурсов Windows Server 2003 . Вы также получаете массу других полезных инструментов и командных портов Unix.

 C:\Documents and Settings\Rob>timeit sleep 3

Version Number:   Windows NT 5.1 (Build 2600)
Exit Time:        2:40 pm, Thursday, December 10 2009
Elapsed Time:     0:00:03.296
Process Time:     0:00:00.015
System Calls:     7576
Context Switches: 1974
Page Faults:      1072
Bytes Read:       6172
Bytes Written:    11086
Bytes Other:      144432
 
0

Если вы не против использования стороннего EXE для помощи, timer.exe от Gammadyne очень полезен.

 setlocal ENABLEEXTENSIONS
FOR /F %%G IN ('timer') DO SET start_time=%%G

@rem Do your work Here
call userscript.bat %*

timer %start_time% "Total time"
endlocal
 
4

Это пакетный сценарий DOS, который вычислит для вас разницу во времени, а не просто выполняет echo %time%.

Следующий код будет работать нормально, если для запуска «пользовательского раздела» требуется не более 24 часов. Пожалуйста, простите меня или дайте мне предложения, это незавершенная работа, на которую я потратил около часа.

Замените "PAUSE" вызовом вашего скрипта, чтобы синхронизировать ваш собственный код.

СЛЕДУЕТ ФАЙЛ DOS BAT:

Примечание: было отредактировано, чтобы исправить проблему с восьмеричным, а не десятичным начальным нулем.

Примечание: было отредактировано, чтобы обрабатывать циклический переход за полночный час и выводить ведущие нули.

 @echo off
@rem --------------------------------------------
setlocal ENABLEEXTENSIONS

set start_time=%time%
echo Beginning at: %start_time%
echo Running Timed Batch File
echo.

@rem echo %*  <-- Extension for all args -- easier than following line
@rem echo %0 %1 %2 %3 %4 %5 %6 %7 %8 %9 ... ...

@rem DO YOUR WORK HERE -- see "call" / PAUSE is here to "fake" work
@rem call userscript.bat %*
PAUSE

set stop_time=%time%
echo.
echo Timed Batch File Completed
echo Start time: %start_time%
echo Stop time : %stop_time%


set TEMPRESULT=%start_time:~0,2%
call:FN_REMOVELEADINGZEROS
set start_hour=%TEMPRESULT%
@rem
set TEMPRESULT=%start_time:~3,2%
call:FN_REMOVELEADINGZEROS
set start_min=%TEMPRESULT%
@rem
set TEMPRESULT=%start_time:~6,2%
call:FN_REMOVELEADINGZEROS
set start_sec=%TEMPRESULT%
@rem
set TEMPRESULT=%start_time:~9,2%
call:FN_REMOVELEADINGZEROS
set start_hundredths=%TEMPRESULT%

set TEMPRESULT=%stop_time:~0,2%
call:FN_REMOVELEADINGZEROS
set stop_hour=%TEMPRESULT%
@rem
set TEMPRESULT=%stop_time:~3,2%
call:FN_REMOVELEADINGZEROS
set stop_min=%TEMPRESULT%
@rem
set TEMPRESULT=%stop_time:~6,2%
call:FN_REMOVELEADINGZEROS
set stop_sec=%TEMPRESULT%
@rem
set TEMPRESULT=%stop_time:~9,2%
call:FN_REMOVELEADINGZEROS
set stop_hundredths=%TEMPRESULT%

set /A start_total=(((((%start_hour%*60)+%start_min%)*60)+%start_sec%)*100)+%start_hundredths%
set /A stop_total=(((((%stop_hour%*60)+%stop_min%)*60)+%stop_sec%)*100)+%stop_hundredths%

set /A total_time=%stop_total% - %start_total%

set /A total_hundredths=%total_time% %% 100
set total_hundredths=00%total_hundredths%
set total_hundredths=%total_hundredths:~-2%
set /A total_time=%total_time% / 100

set /A total_sec="%total_time% %% 60"
set total_sec=00%total_sec%
set total_sec=%total_sec:~-2%
set /A total_time=%total_time% / 60

set /A total_min="%total_time% %% 60"
set total_min=00%total_min%
set total_min=%total_min:~-2%
set /A total_time=%total_time% / 60

set /A total_hour="%total_time% %% 60"
@rem Handle if it wrapped around over midnight
if "%total_hour:~0,1%"=="-" set /A total_hour=%total_hour% + 24

echo Total time: %total_hour%:%total_min%:%total_sec%.%total_hundredths%

@rem --------------------------------------------
@rem Exit the BAT Program
endlocal
goto END

@rem --------------------------------------------
@rem FN_REMOVELEADINGZEROS function
@rem  Used to remove leading zeros from Decimal
@rem  numbers so they are not treated as Octal.
:FN_REMOVELEADINGZEROS
if "%TEMPRESULT%"=="0" goto END
if "%TEMPRESULT:~0,1%" NEQ "0" goto END
set TEMPRESULT=%TEMPRESULT:~1%
goto FN_REMOVELEADINGZEROS

@rem --------------------------------------------
@rem BAT PROGRAM / FUNCTION FILE EXIT
:END